com.neolao.controls.EnterFrame

EnterFrame global.

Classes recquises:

Exemples

// On associe une fonction a un clip
// La fonction va etre executee avec comme base le clip specifié
EnterFrame.addListener(this.monClip_mc, this.maFonction);
 
// Destruction
EnterFrame.remove;

Propriétés

Visibilité Type Nom Status Description
static public Boolean include Lecture seule Creation du clip qui tue la mort
static public Boolean remove Lecture seule Destruction du clip qui tue la mort

Méthodes

Visibilité Return Nom Param 1 Param 2 Description
static public Void init Initialisation
static public Number addListener pTarget:Object pFunction:Function Ajoute une cible à la liste
static public Boolean removeListener pTarget:Object Supprime une cible de la liste

Source

import com.neolao.controls.BroadcastMessages;
/**
 * @author 		neolao <neo@neolao.com>
 * @version 		1.4 (23/02/2005)
 * @link		http://resources.neolao.com/flash/classes/controls/EnterFrame
 * @license		http://creativecommons.org/licenses/by-sa/2.0/
 */
class com.neolao.controls.EnterFrame{
	public static var className:String = "EnterFrame";
	public static var version:String = "1.4";
 
	// ----------------------------- CONSTANTES --------------------------------
 
	// ----------------------------- VARIABLES ---------------------------------
	public static var _include:EnterFrame;
	public static var _broadcastMessages:BroadcastMessages;
 
	// ----------------------------- EVENEMENTS --------------------------------
 
	/*============================= CONSTRUCTEUR =============================*/
	/*========================================================================*/
	/**
	 * Création du clip qui tue la mort
	 */
	function EnterFrame(){
		var mc:MovieClip;
		var depth:Number;
 
		if(!_level0.__OnEnterFrameNeolao){
			depth = _freeDepth(-9800);
			mc = _level0.createEmptyMovieClip("__OnEnterFrameNeolao", depth);
			_broadcastMessages = new BroadcastMessages("EnterFrame");
			mc.onEnterFrame = onEnterFrame;
		}
	}
	/*======================= FIN = CONSTRUCTEUR = FIN =======================*/
	/*========================================================================*/
 
	/*=========================== METHODES PRIVEES ===========================*/
	/*========================================================================*/
	/**
	 * Methode recursive servant a trouver une profondeur libre
	 * @param profondeur Une profondeur de base pour la recherche d'une profondeur libre
	 * @returns Une profondeur libre
	 */
	private function _freeDepth(profondeur:Number):Number{
        if(_level0.getInstanceAtDepth(profondeur) != undefined){
        	return _freeDepth(profondeur - 1);
        }else{
			return profondeur;
		}
    }
	/*===================== FIN = METHODES PRIVEES = FIN =====================*/
	/*========================================================================*/
 
	/*============================ GETTER  SETTER ============================*/
	/*========================================================================*/
	/**
	 * Creation du clip qui tue la mort
	 */
	public static function get include():Boolean{
		_include = new EnterFrame();
		return true;
	}
	/**
	 * Destruction du clip qui tue la mort
	 */
	public static function get remove():Boolean{
		_level0.__OnEnterFrameNeolao.unloadMovie();
		return true;
	}
	/*====================== FIN = GETTER  SETTER = FIN ======================*/
	/*========================================================================*/
 
	/*========================== METHODES PUBLIQUES ==========================*/
	/*========================================================================*/
	/**
	 * Initialisation
	 */
	public static function init(){
		_include = new EnterFrame();
	}
	/**
	 * Broadcast
	 */
	public function onEnterFrame(){
		_broadcastMessages.sendMessage("__EnterFrameNeolao");
	}
	/**
	 * Ajoute une cible à la liste
	 * @param pTarget La cible à ajouter
	 * @param pFunction La fonction qui sera executee a chaque frame
	 * @return La taille de la liste
	 */
	public static function addListener(pTarget:Object, pFunction:Function):Number{
		var o:Boolean = include;
 
		pTarget.__EnterFrameNeolao = pFunction;
		return _broadcastMessages.addListener(pTarget);
	}
	/**
	 * Supprime une cible de la liste
	 * @param pTarget La cible à supprimer
	 * @return true si l'operation a bien été effectuée
	 */
	public static function removeListener(pTarget:Object):Boolean{
		return _broadcastMessages.removeListener(pTarget);
	}
	/*==================== FIN = METHODES PUBLIQUES = FIN ====================*/
	/*========================================================================*/
}